          REAL             FUNCTION CLANHP( NORM, UPLO, N, AP, WORK )
    *
    *  -- LAPACK auxiliary routine (version 3.1) --
    *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
    *     November 2006
    *
    *     .. Scalar Arguments ..
          CHARACTER          NORM, UPLO
          INTEGER            N
    *     ..
    *     .. Array Arguments ..
          REAL               WORK( * )
          COMPLEX            AP( * )
    *     ..
    *
    *  Purpose
    *  =======
    *
    *  CLANHP  returns the value of the one norm,  or the Frobenius norm, or
    *  the  infinity norm,  or the  element of  largest absolute value  of a
    *  complex hermitian matrix A,  supplied in packed form.
    *
    *  Description
    *  ===========
    *
    *  CLANHP returns the value
    *
    *     CLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
    *              (
    *              ( norm1(A),         NORM = '1', 'O' or 'o'
    *              (
    *              ( normI(A),         NORM = 'I' or 'i'
    *              (
    *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
    *
    *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
    *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
    *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
    *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
    *
    *  Arguments
    *  =========
    *
    *  NORM    (input) CHARACTER*1
    *          Specifies the value to be returned in CLANHP as described
    *          above.
    *
    *  UPLO    (input) CHARACTER*1
    *          Specifies whether the upper or lower triangular part of the
    *          hermitian matrix A is supplied.
    *          = 'U':  Upper triangular part of A is supplied
    *          = 'L':  Lower triangular part of A is supplied
    *
    *  N       (input) INTEGER
    *          The order of the matrix A.  N >= 0.  When N = 0, CLANHP is
    *          set to zero.
    *
    *  AP      (input) COMPLEX array, dimension (N*(N+1)/2)
    *          The upper or lower triangle of the hermitian matrix A, packed
    *          columnwise in a linear array.  The j-th column of A is stored
    *          in the array AP as follows:
    *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
    *          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
    *          Note that the  imaginary parts of the diagonal elements need
    *          not be set and are assumed to be zero.
    *
    *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
    *          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
    *          WORK is not referenced.
    *
    * =====================================================================
    *
    *     .. Parameters ..
          REAL               ONE, ZERO
          PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
    *     ..
    *     .. Local Scalars ..
          INTEGER            I, J, K
          REAL               ABSA, SCALE, SUM, VALUE
    *     ..
    *     .. External Functions ..
          LOGICAL            LSAME
          EXTERNAL           LSAME
    *     ..
    *     .. External Subroutines ..
          EXTERNAL           CLASSQ
    *     ..
    *     .. Intrinsic Functions ..
          INTRINSIC          ABS, MAX, REAL, SQRT
    *     ..
    *     .. Executable Statements ..
    *
          IF( N.EQ.0 ) THEN
             VALUE = ZERO
          ELSE IF( LSAME( NORM, 'M' ) ) THEN
    *
    *        Find max(abs(A(i,j))).
    *
             VALUE = ZERO
             IF( LSAME( UPLO, 'U' ) ) THEN
                K = 0
                DO 20 J = 1, N
                   DO 10 I = K + 1, K + J - 1
                      VALUE = MAX( VALUE, ABS( AP( I ) ) )
       10          CONTINUE
                   K = K + J
                   VALUE = MAX( VALUE, ABS( REAL( AP( K ) ) ) )
       20       CONTINUE
             ELSE
                K = 1
                DO 40 J = 1, N
                   VALUE = MAX( VALUE, ABS( REAL( AP( K ) ) ) )
                   DO 30 I = K + 1, K + N - J
                      VALUE = MAX( VALUE, ABS( AP( I ) ) )
       30          CONTINUE
                   K = K + N - J + 1
       40       CONTINUE
             END IF
          ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
         $         ( NORM.EQ.'1' ) ) THEN
    *
    *        Find normI(A) ( = norm1(A), since A is hermitian).
    *
             VALUE = ZERO
             K = 1
             IF( LSAME( UPLO, 'U' ) ) THEN
                DO 60 J = 1, N
                   SUM = ZERO
                   DO 50 I = 1, J - 1
                      ABSA = ABS( AP( K ) )
                      SUM = SUM + ABSA
                      WORK( I ) = WORK( I ) + ABSA
                      K = K + 1
       50          CONTINUE
                   WORK( J ) = SUM + ABS( REAL( AP( K ) ) )
                   K = K + 1
       60       CONTINUE
                DO 70 I = 1, N
                   VALUE = MAX( VALUE, WORK( I ) )
       70       CONTINUE
             ELSE
                DO 80 I = 1, N
                   WORK( I ) = ZERO
       80       CONTINUE
                DO 100 J = 1, N
                   SUM = WORK( J ) + ABS( REAL( AP( K ) ) )
                   K = K + 1
                   DO 90 I = J + 1, N
                      ABSA = ABS( AP( K ) )
                      SUM = SUM + ABSA
                      WORK( I ) = WORK( I ) + ABSA
                      K = K + 1
       90          CONTINUE
                   VALUE = MAX( VALUE, SUM )
      100       CONTINUE
             END IF
          ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
    *
    *        Find normF(A).
    *
             SCALE = ZERO
             SUM = ONE
             K = 2
             IF( LSAME( UPLO, 'U' ) ) THEN
                DO 110 J = 2, N
                   CALL CLASSQ( J-1, AP( K ), 1, SCALE, SUM )
                   K = K + J
      110       CONTINUE
             ELSE
                DO 120 J = 1, N - 1
                   CALL CLASSQ( N-J, AP( K ), 1, SCALE, SUM )
                   K = K + N - J + 1
      120       CONTINUE
             END IF
             SUM = 2*SUM
             K = 1
             DO 130 I = 1, N
                IF( REAL( AP( K ) ).NE.ZERO ) THEN
                   ABSA = ABS( REAL( AP( K ) ) )
                   IF( SCALE.LT.ABSA ) THEN
                      SUM = ONE + SUM*( SCALE / ABSA )**2
                      SCALE = ABSA
                   ELSE
                      SUM = SUM + ( ABSA / SCALE )**2
                   END IF
                END IF
                IF( LSAME( UPLO, 'U' ) ) THEN
                   K = K + I + 1
                ELSE
                   K = K + N - I + 1
                END IF
      130    CONTINUE
             VALUE = SCALE*SQRT( SUM )
          END IF
    *
          CLANHP = VALUE
          RETURN
    *
    *     End of CLANHP
    *
          END