          REAL             FUNCTION SLANGE( NORM, M, N, A, LDA, WORK )
    *
    *  -- LAPACK auxiliary routine (version 3.1) --
    *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
    *     November 2006
    *
    *     .. Scalar Arguments ..
          CHARACTER          NORM
          INTEGER            LDA, M, N
    *     ..
    *     .. Array Arguments ..
          REAL               A( LDA, * ), WORK( * )
    *     ..
    *
    *  Purpose
    *  =======
    *
    *  SLANGE  returns the value of the one norm,  or the Frobenius norm, or
    *  the  infinity norm,  or the  element of  largest absolute value  of a
    *  real matrix A.
    *
    *  Description
    *  ===========
    *
    *  SLANGE returns the value
    *
    *     SLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
    *              (
    *              ( norm1(A),         NORM = '1', 'O' or 'o'
    *              (
    *              ( normI(A),         NORM = 'I' or 'i'
    *              (
    *              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
    *
    *  where  norm1  denotes the  one norm of a matrix (maximum column sum),
    *  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
    *  normF  denotes the  Frobenius norm of a matrix (square root of sum of
    *  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
    *
    *  Arguments
    *  =========
    *
    *  NORM    (input) CHARACTER*1
    *          Specifies the value to be returned in SLANGE as described
    *          above.
    *
    *  M       (input) INTEGER
    *          The number of rows of the matrix A.  M >= 0.  When M = 0,
    *          SLANGE is set to zero.
    *
    *  N       (input) INTEGER
    *          The number of columns of the matrix A.  N >= 0.  When N = 0,
    *          SLANGE is set to zero.
    *
    *  A       (input) REAL array, dimension (LDA,N)
    *          The m by n matrix A.
    *
    *  LDA     (input) INTEGER
    *          The leading dimension of the array A.  LDA >= max(M,1).
    *
    *  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
    *          where LWORK >= M when NORM = 'I'; otherwise, WORK is not
    *          referenced.
    *
    * =====================================================================
    *
    *     .. Parameters ..
          REAL               ONE, ZERO
          PARAMETER          ( ONE = 1.0E+0, ZERO = 0.0E+0 )
    *     ..
    *     .. Local Scalars ..
          INTEGER            I, J
          REAL               SCALE, SUM, VALUE
    *     ..
    *     .. External Subroutines ..
          EXTERNAL           SLASSQ
    *     ..
    *     .. External Functions ..
          LOGICAL            LSAME
          EXTERNAL           LSAME
    *     ..
    *     .. Intrinsic Functions ..
          INTRINSIC          ABS, MAX, MIN, SQRT
    *     ..
    *     .. Executable Statements ..
    *
          IF( MIN( M, N ).EQ.0 ) THEN
             VALUE = ZERO
          ELSE IF( LSAME( NORM, 'M' ) ) THEN
    *
    *        Find max(abs(A(i,j))).
    *
             VALUE = ZERO
             DO 20 J = 1, N
                DO 10 I = 1, M
                   VALUE = MAX( VALUE, ABS( A( I, J ) ) )
       10       CONTINUE
       20    CONTINUE
          ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
    *
    *        Find norm1(A).
    *
             VALUE = ZERO
             DO 40 J = 1, N
                SUM = ZERO
                DO 30 I = 1, M
                   SUM = SUM + ABS( A( I, J ) )
       30       CONTINUE
                VALUE = MAX( VALUE, SUM )
       40    CONTINUE
          ELSE IF( LSAME( NORM, 'I' ) ) THEN
    *
    *        Find normI(A).
    *
             DO 50 I = 1, M
                WORK( I ) = ZERO
       50    CONTINUE
             DO 70 J = 1, N
                DO 60 I = 1, M
                   WORK( I ) = WORK( I ) + ABS( A( I, J ) )
       60       CONTINUE
       70    CONTINUE
             VALUE = ZERO
             DO 80 I = 1, M
                VALUE = MAX( VALUE, WORK( I ) )
       80    CONTINUE
          ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
    *
    *        Find normF(A).
    *
             SCALE = ZERO
             SUM = ONE
             DO 90 J = 1, N
                CALL SLASSQ( M, A( 1, J ), 1, SCALE, SUM )
       90    CONTINUE
             VALUE = SCALE*SQRT( SUM )
          END IF
    *
          SLANGE = VALUE
          RETURN
    *
    *     End of SLANGE
    *
          END