\begin{code}
{-# OPTIONS -fno-implicit-prelude #-}
-----------------------------------------------------------------------------
-- |
-- Module      :  GHC.IOBase
-- Copyright   :  (c) The University of Glasgow 1994-2002
-- License     :  see libraries/base/LICENSE
-- 
-- Maintainer  :  cvs-ghc@haskell.org
-- Stability   :  internal
-- Portability :  non-portable (GHC Extensions)
--
-- Definitions for the 'IO' monad and its friends.
--
-----------------------------------------------------------------------------

module GHC.IOBase where

import GHC.ST
import GHC.STRef
import GHC.Base
import GHC.Num	-- To get fromInteger etc, needed because of -fno-implicit-prelude
import Data.Maybe  ( Maybe(..) )
import GHC.Show
import GHC.List
import GHC.Read

#ifndef __HADDOCK__
import {-# SOURCE #-} Data.Dynamic
#endif

-- ---------------------------------------------------------------------------
-- The IO Monad

{-
The IO Monad is just an instance of the ST monad, where the state is
the real world.  We use the exception mechanism (in GHC.Exception) to
implement IO exceptions.

NOTE: The IO representation is deeply wired in to various parts of the
system.  The following list may or may not be exhaustive:

Compiler  - types of various primitives in PrimOp.lhs

RTS 	  - forceIO (StgMiscClosures.hc)
	  - catchzh_fast, (un)?blockAsyncExceptionszh_fast, raisezh_fast 
	    (Exceptions.hc)
	  - raiseAsync (Schedule.c)

Prelude   - GHC.IOBase.lhs, and several other places including
	    GHC.Exception.lhs.

Libraries - parts of hslibs/lang.

--SDM
-}

{-|
A value of type @'IO' a@ is a computation which, when performed,
does some I\/O before returning a value of type @a@.  

There is really only one way to \"perform\" an I\/O action: bind it to
@Main.main@ in your program.  When your program is run, the I\/O will
be performed.  It isn't possible to perform I\/O from an arbitrary
function, unless that function is itself in the 'IO' monad and called
at some point, directly or indirectly, from @Main.main@.

'IO' is a monad, so 'IO' actions can be combined using either the do-notation
or the '>>' and '>>=' operations from the 'Monad' class.
-}
newtype IO a = IO (State# RealWorld -> (# State# RealWorld, a #))

unIO :: IO a -> (State# RealWorld -> (# State# RealWorld, a #))
unIO (IO a) = a

instance  Functor IO where
   fmap f x = x >>= (return . f)

instance  Monad IO  where
    {-# INLINE return #-}
    {-# INLINE (>>)   #-}
    {-# INLINE (>>=)  #-}
    m >> k      =  m >>= \ _ -> k
    return x	= returnIO x

    m >>= k     = bindIO m k
    fail s	= failIO s

failIO :: String -> IO a
failIO s = ioError (userError s)

liftIO :: IO a -> State# RealWorld -> STret RealWorld a
liftIO (IO m) = \s -> case m s of (# s', r #) -> STret s' r

bindIO :: IO a -> (a -> IO b) -> IO b
bindIO (IO m) k = IO ( \ s ->
  case m s of 
    (# new_s, a #) -> unIO (k a) new_s
  )

thenIO :: IO a -> IO b -> IO b
thenIO (IO m) k = IO ( \ s ->
  case m s of 
    (# new_s, a #) -> unIO k new_s
  )

returnIO :: a -> IO a
returnIO x = IO (\ s -> (# s, x #))

-- ---------------------------------------------------------------------------
-- Coercions between IO and ST

--stToIO        :: (forall s. ST s a) -> IO a
stToIO	      :: ST RealWorld a -> IO a
stToIO (ST m) = IO m

ioToST	      :: IO a -> ST RealWorld a
ioToST (IO m) = (ST m)

-- ---------------------------------------------------------------------------
-- Unsafe IO operations

{-|
This is the "back door" into the 'IO' monad, allowing
'IO' computation to be performed at any time.  For
this to be safe, the 'IO' computation should be
free of side effects and independent of its environment.

If the I\/O computation wrapped in 'unsafePerformIO'
performs side effects, then the relative order in which those side
effects take place (relative to the main I\/O trunk, or other calls to
'unsafePerformIO') is indeterminate.  

However, it is less well known that
'unsafePerformIO' is not type safe.  For example:

>     test :: IORef [a]
>     test = unsafePerformIO $ newIORef []
>     
>     main = do
>     	      writeIORef test [42]
>     	      bang \<- readIORef test
>     	      print (bang :: [Char])

This program will core dump.  This problem with polymorphic references
is well known in the ML community, and does not arise with normal
monadic use of references.  There is no easy way to make it impossible
once you use 'unsafePerformIO'.  Indeed, it is
possible to write @coerce :: a -> b@ with the
help of 'unsafePerformIO'.  So be careful!
-}
{-# NOINLINE unsafePerformIO #-}
unsafePerformIO	:: IO a -> a
unsafePerformIO (IO m) = case m realWorld# of (# _, r #)   -> r

{-|
'unsafeInterleaveIO' allows 'IO' computation to be deferred lazily.
When passed a value of type @IO a@, the 'IO' will only be performed
when the value of the @a@ is demanded.  This is used to implement lazy
file reading, see 'System.IO.hGetContents'.
-}
{-# NOINLINE unsafeInterleaveIO #-}
unsafeInterleaveIO :: IO a -> IO a
unsafeInterleaveIO (IO m)
  = IO ( \ s -> let
		   r = case m s of (# _, res #) -> res
		in
		(# s, r #))

-- ---------------------------------------------------------------------------
-- Handle type

data MVar a = MVar (MVar# RealWorld a)
{- ^
An 'MVar' (pronounced \"em-var\") is a synchronising variable, used
for communication between concurrent threads.  It can be thought of
as a a box, which may be empty or full.
-}

-- pull in Eq (Mvar a) too, to avoid GHC.Conc being an orphan-instance module
instance Eq (MVar a) where
	(MVar mvar1#) == (MVar mvar2#) = sameMVar# mvar1# mvar2#

--  A Handle is represented by (a reference to) a record 
--  containing the state of the I/O port/device. We record
--  the following pieces of info:

--    * type (read,write,closed etc.)
--    * the underlying file descriptor
--    * buffering mode 
--    * buffer, and spare buffers
--    * user-friendly name (usually the
--	FilePath used when IO.openFile was called)

-- Note: when a Handle is garbage collected, we want to flush its buffer
-- and close the OS file handle, so as to free up a (precious) resource.

data Handle 
  = FileHandle				-- A normal handle to a file
	!(MVar Handle__)

  | DuplexHandle			-- A handle to a read/write stream
	!(MVar Handle__)		-- The read side
	!(MVar Handle__)		-- The write side

-- NOTES:
--    * A 'FileHandle' is seekable.  A 'DuplexHandle' may or may not be
--      seekable.

instance Eq Handle where
 (FileHandle h1)     == (FileHandle h2)     = h1 == h2
 (DuplexHandle h1 _) == (DuplexHandle h2 _) = h1 == h2
 _ == _ = False 

type FD = Int -- XXX ToDo: should be CInt

data Handle__
  = Handle__ {
      haFD	    :: !FD,		     -- file descriptor
      haType        :: HandleType,	     -- type (read/write/append etc.)
      haIsBin       :: Bool,		     -- binary mode?
      haIsStream    :: Bool,		     -- is this a stream handle?
      haBufferMode  :: BufferMode,	     -- buffer contains read/write data?
      haFilePath    :: FilePath,	     -- file name, possibly
      haBuffer	    :: !(IORef Buffer),	     -- the current buffer
      haBuffers     :: !(IORef BufferList),  -- spare buffers
      haOtherSide   :: Maybe (MVar Handle__) -- ptr to the write side of a 
					     -- duplex handle.
    }

-- ---------------------------------------------------------------------------
-- Buffers

-- The buffer is represented by a mutable variable containing a
-- record, where the record contains the raw buffer and the start/end
-- points of the filled portion.  We use a mutable variable so that
-- the common operation of writing (or reading) some data from (to)
-- the buffer doesn't need to modify, and hence copy, the handle
-- itself, it just updates the buffer.  

-- There will be some allocation involved in a simple hPutChar in
-- order to create the new Buffer structure (below), but this is
-- relatively small, and this only has to be done once per write
-- operation.

-- The buffer contains its size - we could also get the size by
-- calling sizeOfMutableByteArray# on the raw buffer, but that tends
-- to be rounded up to the nearest Word.

type RawBuffer = MutableByteArray# RealWorld

-- INVARIANTS on a Buffer:
--
--   * A handle *always* has a buffer, even if it is only 1 character long
--     (an unbuffered handle needs a 1 character buffer in order to support
--      hLookAhead and hIsEOF).
--   * r <= w
--   * if r == w, then r == 0 && w == 0
--   * if state == WriteBuffer, then r == 0
--   * a write buffer is never full.  If an operation
--     fills up the buffer, it will always flush it before 
--     returning.
--   * a read buffer may be full as a result of hLookAhead.  In normal
--     operation, a read buffer always has at least one character of space.

data Buffer 
  = Buffer {
	bufBuf   :: RawBuffer,
	bufRPtr  :: !Int,
	bufWPtr  :: !Int,
	bufSize  :: !Int,
	bufState :: BufferState
  }

data BufferState = ReadBuffer | WriteBuffer deriving (Eq)

-- we keep a few spare buffers around in a handle to avoid allocating
-- a new one for each hPutStr.  These buffers are *guaranteed* to be the
-- same size as the main buffer.
data BufferList 
  = BufferListNil 
  | BufferListCons RawBuffer BufferList


bufferIsWritable :: Buffer -> Bool
bufferIsWritable Buffer{ bufState=WriteBuffer } = True
bufferIsWritable _other = False

bufferEmpty :: Buffer -> Bool
bufferEmpty Buffer{ bufRPtr=r, bufWPtr=w } = r == w

-- only makes sense for a write buffer
bufferFull :: Buffer -> Bool
bufferFull b@Buffer{ bufWPtr=w } = w >= bufSize b

--  Internally, we classify handles as being one
--  of the following:

data HandleType
 = ClosedHandle
 | SemiClosedHandle
 | ReadHandle
 | WriteHandle
 | AppendHandle
 | ReadWriteHandle

isReadableHandleType ReadHandle         = True
isReadableHandleType ReadWriteHandle    = True
isReadableHandleType _	       	        = False

isWritableHandleType AppendHandle    = True
isWritableHandleType WriteHandle     = True
isWritableHandleType ReadWriteHandle = True
isWritableHandleType _	       	     = False

-- File names are specified using @FilePath@, a OS-dependent
-- string that (hopefully, I guess) maps to an accessible file/object.

type FilePath = String

-- ---------------------------------------------------------------------------
-- Buffering modes

-- Three kinds of buffering are supported: line-buffering, 
-- block-buffering or no-buffering.  These modes have the following
-- effects. For output, items are written out from the internal
-- buffer according to the buffer mode:
--
-- o line-buffering  the entire output buffer is written
--   out whenever a newline is output, the output buffer overflows, 
--   a flush is issued, or the handle is closed.
--
-- o block-buffering the entire output buffer is written out whenever 
--   it overflows, a flush is issued, or the handle
--   is closed.
--
-- o no-buffering output is written immediately, and never stored
--   in the output buffer.
--
-- The output buffer is emptied as soon as it has been written out.

-- Similarly, input occurs according to the buffer mode for handle {\em hdl}.

-- o line-buffering when the input buffer for the handle is not empty,
--   the next item is obtained from the buffer;
--   otherwise, when the input buffer is empty,
--   characters up to and including the next newline
--   character are read into the buffer.  No characters
--   are available until the newline character is
--   available.
--
-- o block-buffering when the input buffer for the handle becomes empty,
--   the next block of data is read into this buffer.
--
-- o no-buffering the next input item is read and returned.

-- For most implementations, physical files will normally be block-buffered 
-- and terminals will normally be line-buffered. (the IO interface provides
-- operations for changing the default buffering of a handle tho.)

data BufferMode  
 = NoBuffering | LineBuffering | BlockBuffering (Maybe Int)
   deriving (Eq, Ord, Read, Show)

-- ---------------------------------------------------------------------------
-- IORefs

-- |A mutable variable in the 'IO' monad
newtype IORef a = IORef (STRef RealWorld a) deriving Eq

-- |Build a new 'IORef'
newIORef    :: a -> IO (IORef a)
newIORef v = stToIO (newSTRef v) >>= \ var -> return (IORef var)

-- |Read the value of an 'IORef'
readIORef   :: IORef a -> IO a
readIORef  (IORef var) = stToIO (readSTRef var)

-- |Write a new value into an 'IORef'
writeIORef  :: IORef a -> a -> IO ()
writeIORef (IORef var) v = stToIO (writeSTRef var v)

-- ---------------------------------------------------------------------------
-- Show instance for Handles

-- handle types are 'show'n when printing error msgs, so
-- we provide a more user-friendly Show instance for it
-- than the derived one.

instance Show HandleType where
  showsPrec p t =
    case t of
      ClosedHandle      -> showString "closed"
      SemiClosedHandle  -> showString "semi-closed"
      ReadHandle        -> showString "readable"
      WriteHandle       -> showString "writable"
      AppendHandle      -> showString "writable (append)"
      ReadWriteHandle   -> showString "read-writable"

instance Show Handle where 
  showsPrec p (FileHandle   h)   = showHandle p h False
  showsPrec p (DuplexHandle _ h) = showHandle p h True
   
showHandle p h duplex =
    let
     -- (Big) SIGH: unfolded defn of takeMVar to avoid
     -- an (oh-so) unfortunate module loop with GHC.Conc.
     hdl_ = unsafePerformIO (IO $ \ s# ->
	     case h                 of { MVar h# ->
	     case takeMVar# h# s#   of { (# s2# , r #) -> 
	     case putMVar# h# r s2# of { s3# ->
	     (# s3#, r #) }}})

     showType | duplex = showString "duplex (read-write)"
	      | otherwise = showsPrec p (haType hdl_)
    in
    showChar '{' . 
    showHdl (haType hdl_) 
	    (showString "loc=" . showString (haFilePath hdl_) . showChar ',' .
	     showString "type=" . showType . showChar ',' .
	     showString "binary=" . showsPrec p (haIsBin hdl_) . showChar ',' .
	     showString "buffering=" . showBufMode (unsafePerformIO (readIORef (haBuffer hdl_))) (haBufferMode hdl_) . showString "}" )
   where

    showHdl :: HandleType -> ShowS -> ShowS
    showHdl ht cont = 
       case ht of
        ClosedHandle  -> showsPrec p ht . showString "}"
	_ -> cont
       
    showBufMode :: Buffer -> BufferMode -> ShowS
    showBufMode buf bmo =
      case bmo of
        NoBuffering   -> showString "none"
	LineBuffering -> showString "line"
	BlockBuffering (Just n) -> showString "block " . showParen True (showsPrec p n)
	BlockBuffering Nothing  -> showString "block " . showParen True (showsPrec p def)
      where
       def :: Int 
       def = bufSize buf

-- ------------------------------------------------------------------------
-- Exception datatype and operations

-- |The type of exceptions.  Every kind of system-generated exception
-- has a constructor in the 'Exception' type, and values of other
-- types may be injected into 'Exception' by coercing them to
-- 'Dynamic' (see the section on Dynamic Exceptions).
--
-- For backwards compatibility with Haskell 98, 'IOError' is a type synonym
-- for 'Exception'.
data Exception
  = ArithException  	ArithException
	-- ^Exceptions raised by arithmetic
	-- operations.  (NOTE: GHC currently does not throw
	-- 'ArithException's except for 'DivideByZero').
  | ArrayException	ArrayException
	-- ^Exceptions raised by array-related
	-- operations.  (NOTE: GHC currently does not throw
	-- 'ArrayException's).
  | AssertionFailed	String
	-- ^This exception is thrown by the
	-- 'assert' operation when the condition
	-- fails.  The 'String' argument contains the
	-- location of the assertion in the source program.
  | AsyncException	AsyncException
	-- ^Asynchronous exceptions (see section on Asynchronous Exceptions).
  | BlockedOnDeadMVar
	-- ^The current thread was executing a call to
	-- 'takeMVar' that could never return, because there are no other
	-- references to this 'MVar'.
  | Deadlock
	-- ^There are no runnable threads, so the program is
	-- deadlocked.  The 'Deadlock' exception is
	-- raised in the main thread only (see also: "Control.Concurrent").
  | DynException	Dynamic
	-- ^Dynamically typed exceptions (see section on Dynamic Exceptions).
  | ErrorCall		String
	-- ^The 'ErrorCall' exception is thrown by 'error'.  The 'String'
	-- argument of 'ErrorCall' is the string passed to 'error' when it was
	-- called.
  | ExitException	ExitCode
	-- ^The 'ExitException' exception is thrown by 'System.exitWith' (and
	-- 'System.exitFailure').  The 'ExitCode' argument is the value passed 
	-- to 'System.exitWith'.  An unhandled 'ExitException' exception in the
	-- main thread will cause the program to be terminated with the given 
	-- exit code.
  | IOException 	IOException
	-- ^These are the standard IO exceptions generated by
  	-- Haskell\'s @IO@ operations.  See also "System.IO.Error".
  | NoMethodError       String
	-- ^An attempt was made to invoke a class method which has
	-- no definition in this instance, and there was no default
	-- definition given in the class declaration.  GHC issues a
	-- warning when you compile an instance which has missing
	-- methods.
  | NonTermination
	-- ^The current thread is stuck in an infinite loop.  This
	-- exception may or may not be thrown when the program is
	-- non-terminating.
  | PatternMatchFail	String
	-- ^A pattern matching failure.  The 'String' argument should contain a
	-- descriptive message including the function name, source file
	-- and line number.
  | RecConError		String
	-- ^An attempt was made to evaluate a field of a record
	-- for which no value was given at construction time.  The
	-- 'String' argument gives the location of the
	-- record construction in the source program.
  | RecSelError		String
	-- ^A field selection was attempted on a constructor that
	-- doesn\'t have the requested field.  This can happen with
	-- multi-constructor records when one or more fields are
	-- missing from some of the constructors.  The
	-- 'String' argument gives the location of the
	-- record selection in the source program.
  | RecUpdError		String
	-- ^An attempt was made to update a field in a record,
	-- where the record doesn\'t have the requested field.  This can
	-- only occur with multi-constructor records, when one or more
	-- fields are missing from some of the constructors.  The
	-- 'String' argument gives the location of the
	-- record update in the source program.

-- |The type of arithmetic exceptions
data ArithException
  = Overflow
  | Underflow
  | LossOfPrecision
  | DivideByZero
  | Denormal
  deriving (Eq, Ord)


-- |Asynchronous exceptions
data AsyncException
  = StackOverflow
	-- ^The current thread\'s stack exceeded its limit.
	-- Since an exception has been raised, the thread\'s stack
	-- will certainly be below its limit again, but the
	-- programmer should take remedial action
	-- immediately.
  | HeapOverflow
	-- ^The program\'s heap is reaching its limit, and
	-- the program should take action to reduce the amount of
	-- live data it has. Notes:
	--
	-- 	* It is undefined which thread receives this exception.
	--
	-- 	* GHC currently does not throw 'HeapOverflow' exceptions.
  | ThreadKilled
	-- ^This exception is raised by another thread
	-- calling 'killThread', or by the system
	-- if it needs to terminate the thread for some
	-- reason.
  deriving (Eq, Ord)

-- | Exceptions generated by array operations
data ArrayException
  = IndexOutOfBounds  	String
	-- ^An attempt was made to index an array outside
	-- its declared bounds.
  | UndefinedElement	String
	-- ^An attempt was made to evaluate an element of an
	-- array that had not been initialized.
  deriving (Eq, Ord)

stackOverflow, heapOverflow :: Exception -- for the RTS
stackOverflow = AsyncException StackOverflow
heapOverflow  = AsyncException HeapOverflow

instance Show ArithException where
  showsPrec _ Overflow        = showString "arithmetic overflow"
  showsPrec _ Underflow       = showString "arithmetic underflow"
  showsPrec _ LossOfPrecision = showString "loss of precision"
  showsPrec _ DivideByZero    = showString "divide by zero"
  showsPrec _ Denormal        = showString "denormal"

instance Show AsyncException where
  showsPrec _ StackOverflow   = showString "stack overflow"
  showsPrec _ HeapOverflow    = showString "heap overflow"
  showsPrec _ ThreadKilled    = showString "thread killed"

instance Show ArrayException where
  showsPrec _ (IndexOutOfBounds s)
	= showString "array index out of range"
	. (if not (null s) then showString ": " . showString s
			   else id)
  showsPrec _ (UndefinedElement s)
	= showString "undefined array element"
	. (if not (null s) then showString ": " . showString s
			   else id)

instance Show Exception where
  showsPrec _ (IOException err)	         = shows err
  showsPrec _ (ArithException err)       = shows err
  showsPrec _ (ArrayException err)       = shows err
  showsPrec _ (ErrorCall err)	         = showString err
  showsPrec _ (ExitException err)        = showString "exit: " . shows err
  showsPrec _ (NoMethodError err)        = showString err
  showsPrec _ (PatternMatchFail err)     = showString err
  showsPrec _ (RecSelError err)	         = showString err
  showsPrec _ (RecConError err)	         = showString err
  showsPrec _ (RecUpdError err)	         = showString err
  showsPrec _ (AssertionFailed err)      = showString err
  showsPrec _ (DynException _err)        = showString "unknown exception"
  showsPrec _ (AsyncException e)	 = shows e
  showsPrec _ (BlockedOnDeadMVar)	 = showString "thread blocked indefinitely"
  showsPrec _ (NonTermination)           = showString "<<loop>>"
  showsPrec _ (Deadlock)                 = showString "<<deadlock>>"

instance Eq Exception where
  IOException e1      == IOException e2      = e1 == e2
  ArithException e1   == ArithException e2   = e1 == e2
  ArrayException e1   == ArrayException e2   = e1 == e2
  ErrorCall e1        == ErrorCall e2	     = e1 == e2
  ExitException	e1    == ExitException e2    = e1 == e2
  NoMethodError e1    == NoMethodError e2    = e1 == e2
  PatternMatchFail e1 == PatternMatchFail e2 = e1 == e2
  RecSelError e1      == RecSelError e2      = e1 == e2
  RecConError e1      == RecConError e2      = e1 == e2
  RecUpdError e1      == RecUpdError e2      = e1 == e2
  AssertionFailed e1  == AssertionFailed e2  = e1 == e2
  DynException _      == DynException _      = False -- incomparable
  AsyncException e1   == AsyncException e2   = e1 == e2
  BlockedOnDeadMVar   == BlockedOnDeadMVar   = True
  NonTermination      == NonTermination      = True
  Deadlock            == Deadlock            = True
  _                   == _                   = False

-- -----------------------------------------------------------------------------
-- The ExitCode type

-- The `ExitCode' type defines the exit codes that a program
-- can return.  `ExitSuccess' indicates successful termination;
-- and `ExitFailure code' indicates program failure
-- with value `code'.  The exact interpretation of `code'
-- is operating-system dependent.  In particular, some values of 
-- `code' may be prohibited (e.g. 0 on a POSIX-compliant system).

-- We need it here because it is used in ExitException in the
-- Exception datatype (above).

data ExitCode = ExitSuccess | ExitFailure Int 
                deriving (Eq, Ord, Read, Show)

-- --------------------------------------------------------------------------
-- Primitive throw

-- | Throw an exception.  Exceptions may be thrown from purely
-- functional code, but may only be caught within the 'IO' monad.
throw :: Exception -> a
throw exception = raise# exception

-- | A variant of 'throw' that can be used within the 'IO' monad.
--
-- Although 'ioError' has a type that is an instance of the type of 'throw', the
-- two functions are subtly different:
--
-- > throw e   `seq` return ()  ===> throw e
-- > ioError e `seq` return ()  ===> return ()
--
-- The first example will cause the exception @e@ to be raised,
-- whereas the second one won\'t.  In fact, 'ioError' will only cause
-- an exception to be raised when it is used within the 'IO' monad.
-- The 'ioError' variant should be used in preference to 'throw' to
-- raise an exception within the 'IO' monad because it guarantees
-- ordering with respect to other 'IO' operations, whereas 'throw'
-- does not.
ioError         :: Exception -> IO a 
ioError err	=  IO $ \s -> throw err s

ioException	:: IOException -> IO a
ioException err =  IO $ \s -> throw (IOException err) s

-- ---------------------------------------------------------------------------
-- IOError type

-- A value @IOError@ encode errors occurred in the @IO@ monad.
-- An @IOError@ records a more specific error type, a descriptive
-- string and maybe the handle that was used when the error was
-- flagged.

type IOError = Exception

data IOException
 = IOError {
     ioe_handle   :: Maybe Handle,   -- the handle used by the action flagging 
				     -- the error.
     ioe_type     :: IOErrorType,    -- what it was.
     ioe_location :: String,	     -- location.
     ioe_descr    :: String,         -- error type specific information.
     ioe_filename :: Maybe FilePath  -- filename the error is related to.
   }

instance Eq IOException where
  (IOError h1 e1 loc1 str1 fn1) == (IOError h2 e2 loc2 str2 fn2) = 
    e1==e2 && str1==str2 && h1==h2 && loc1==loc2 && fn1==fn2

data IOErrorType
  -- Haskell 98:
  = AlreadyExists
  | NoSuchThing
  | ResourceBusy
  | ResourceExhausted
  | EOF
  | IllegalOperation
  | PermissionDenied
  | UserError
  -- GHC only:
  | UnsatisfiedConstraints
  | SystemError
  | ProtocolError
  | OtherError
  | InvalidArgument
  | InappropriateType
  | HardwareFault
  | UnsupportedOperation
  | TimeExpired
  | ResourceVanished
  | Interrupted
  | DynIOError Dynamic -- cheap&cheerful extensible IO error type.

instance Eq IOErrorType where
   x == y = 
     case x of
       DynIOError{} -> False -- from a strictness POV, compatible with a derived Eq inst?
       _ -> getTag x ==# getTag y
 
instance Show IOErrorType where
  showsPrec _ e =
    showString $
    case e of
      AlreadyExists	-> "already exists"
      NoSuchThing       -> "does not exist"
      ResourceBusy      -> "resource busy"
      ResourceExhausted -> "resource exhausted"
      EOF		-> "end of file"
      IllegalOperation	-> "illegal operation"
      PermissionDenied  -> "permission denied"
      UserError		-> "user error"
      HardwareFault	-> "hardware fault"
      InappropriateType -> "inappropriate type"
      Interrupted       -> "interrupted"
      InvalidArgument   -> "invalid argument"
      OtherError        -> "failed"
      ProtocolError     -> "protocol error"
      ResourceVanished  -> "resource vanished"
      SystemError	-> "system error"
      TimeExpired       -> "timeout"
      UnsatisfiedConstraints -> "unsatisified constraints" -- ultra-precise!
      UnsupportedOperation -> "unsupported operation"
      DynIOError{}      -> "unknown IO error"

userError       :: String  -> IOError
userError str	=  IOException (IOError Nothing UserError "" str Nothing)

-- ---------------------------------------------------------------------------
-- Showing IOErrors

instance Show IOException where
    showsPrec p (IOError hdl iot loc s fn) =
      showsPrec p iot .
      (case loc of
         "" -> id
	 _  -> showString "\nAction: " . showString loc) .
      (case hdl of
        Nothing -> id
	Just h  -> showString "\nHandle: " . showsPrec p h) .
      (case s of
	 "" -> id
	 _  -> showString "\nReason: " . showString s) .
      (case fn of
	 Nothing -> id
	 Just name -> showString "\nFile: " . showString name)
\end{code}
