Previous | About HAP: Cohomology With Twisted Coefficients | next

The cohomology of a group G with coefficients in a ZG-module A is defined as:

Hn(G,A) =

Ker( HomZG(Rn,A) → HomZG(Rn+1,A) )

Image( HomZG(Rn-1,A) → HomZG(Rn,A)

When the abelian group underlying A is free of rank n we can encode A as a group homomorphism A:G → GLn(Z).
When G is a permutation group of degree n the free abelian group Zn admits a canonical G-action defined by
g·(x1, x2, ... , xn) = (xg'(1) , xg'(2) , ... , xg'(n))
where g'=g-1, for g in G and xi in Z. This canonical permutation module A can be constructed for any permutation group G using the HAP command PermToMatrixGroup(). For example:

gap> G:=AlternatingGroup(5);; gap> A:=PermToMatrixGroup(G,5); [ (1,2,3,4,5), (3,4,5) ] -> [ [ [ 0, 1, 0, 0, 0 ], [ 0, 0, 1, 0, 0 ], [ 0, 0, 0, 1, 0 ], [ 0, 0, 0, 0, 1 ], [ 1, 0, 0, 0, 0 ] ], [ [ 1, 0, 0, 0, 0 ], [ 0, 1, 0, 0, 0 ], [ 0, 0, 0, 1, 0 ], [ 0, 0, 0, 0, 1 ], [ 0, 0, 1, 0, 0 ] ] ]

The following commands show that:

- the 6th cohomology of the alternating group G=A5 with coefficients in its 5-dimensional canonical permutation module A is H6(G,A) = Z2+Z6.
- The 3rd cohomology of the even subgroup B+ of the 5-string Braid group, again with coefficients in the permutation module A (considered as a B+-module via the quotient homomorphism B+ → A5) is H3(B+,A) = Z2+Z6+Z3.

gap> Alt5:=AlternatingGroup(5);;
gap> A:=PermToMatrixGroup(SymmetricGroup(5),5);;
gap> R:=ResolutionFiniteGroup(Alt5,7);;
gap> TR:=HomToIntegralModule(R,A);;
gap> Cohomology(TR,6);
[ 2, 6 ]
gap> D:=[[1,[2,3]],[2,[3,3]],[3,[4,3]]];;
gap> R:=ResolutionArtinGroup(D,10);;
gap> Brd5:=R.group;; Brd5Gens:=GeneratorsOfGroup(Brd5);;
gap> ImGens:=[Image(A,(1,2)),Image(A,(2,3)),Image(A,(3,4)),Image(A,(4,5))];;
gap> B:=GroupHomomorphismByImages(Brd5,Image(A),Brd5Gens,ImGens);;
gap> EvBrd5:=EvenSubgroup(Brd5);;
gap> S:=ResolutionSubgroup(R,EvBrd5);;
gap> TS:=HomToIntegralModule(S,B);;
gap> Cohomology(TS,3);
[ 2, 6, 0, 0, 0 ]

Such commands can be used, for instance, to produce strong evidence in support of the following.

### Conjecture:

Let Z(n) denote the free abelian group of rank n endowed with the canonical permutation action of the symmetric group Sn. Let Z be the free abelian group of rank 1 with trivial action of Sn. There is an isomorphism
Hk(Sn, Z(n)) = Hk(Sn-1, Z)
for all n>1 and for all k.

The following commands support the conjecture. (It might be possible to use the techniques of [M. Salvetti, "Cohomology of Coxeter groups", Topology and its Applications 118 (2002), 199-208] to prove the conjecture.)

gap> R:=[];;C:=[];;D:=[];;
gap> for n in [2..5] do
> R[n]:=ResolutionFiniteGroup(SymmetricGroup(n),6);
> C[n]:=HomToIntegralModule(R[n],PermToMatrixGroup(SymmetricGroup(n),n));
> D[n]:=HomToIntegers(R[n]);
> od;
gap> for k in [0..5] do
> for n in [2..4] do
> Print("Twisted Cohomology: H",k,"(S",n+1,") = ",Cohomology(C[n+1],k),"\n");
> Print("Integral Cohomology: H",k,"(S",n,") = ",Cohomology(D[n],k),"\n\n");
> od;od;
Twisted Cohomology: H0(S3) = [ 0 ]
Integral Cohomology: H0(S2) = [ 0 ]
Twisted Cohomology: H0(S4) = [ 0 ]
Integral Cohomology: H0(S3) = [ 0 ]
Twisted Cohomology: H0(S5) = [ 0 ]
Integral Cohomology: H0(S4) = [ 0 ]
Twisted Cohomology: H1(S3) = [ ]
Integral Cohomology: H1(S2) = [ ]
Twisted Cohomology: H1(S4) = [ ]
Integral Cohomology: H1(S3) = [ ]
Twisted Cohomology: H1(S5) = [ ]
Integral Cohomology: H1(S4) = [ ]
Twisted Cohomology: H2(S3) = [ 2 ]
Integral Cohomology: H2(S2) = [ 2 ]
Twisted Cohomology: H2(S4) = [ 2 ]
Integral Cohomology: H2(S3) = [ 2 ]
Twisted Cohomology: H2(S5) = [ 2 ]
Integral Cohomology: H2(S4) = [ 2 ]
Twisted Cohomology: H3(S3) = [ ]
Integral Cohomology: H3(S2) = [ ]
Twisted Cohomology: H3(S4) = [ ]
Integral Cohomology: H3(S3) = [ ]
Twisted Cohomology: H3(S5) = [ 2 ]
Integral Cohomology: H3(S4) = [ 2 ]
Twisted Cohomology: H4(S3) = [ 2 ]
Integral Cohomology: H4(S2) = [ 2 ]
Twisted Cohomology: H4(S4) = [ 6 ]
Integral Cohomology: H4(S3) = [ 6 ]
Twisted Cohomology: H4(S5) = [ 2, 12 ]
Integral Cohomology: H4(S4) = [ 2, 12 ]
Twisted Cohomology: H5(S3) = [ ]
Integral Cohomology: H5(S2) = [ ]
Twisted Cohomology: H5(S4) = [ ]
Integral Cohomology: H5(S3) = [ ]
Twisted Cohomology: H5(S5) = [ 2 ]
Integral Cohomology: H5(S4) = [ 2 ]

Previous Page | Contents | Next page