[Up] [Previous] [Next] [Index]

# 2 The User Interface of the AtlasRep Package

### Sections

1. Accessing vs. Constructing Representations
2. Group Names Used in the AtlasRep Package
3. Standard Generators Used in the AtlasRep Package
4. Class Names Used in the AtlasRep Package
5. Accessing Data of the AtlasRep Package
6. Updating the Tables of Contents of the AtlasRep Package
7. Examples of Using the AtlasRep Package

The user interface is the part of the GAP interface that allows one to display information about the current contents of the database and to access individual data (perhaps from a remote server, see Local or Remote Installation of the AtlasRep Package). The corresponding functions are described in this chapter. See the last section for some small examples how to use the functions of the interface.

Extensions of the AtlasRep package are regarded as another part of the GAP interface, they are described in Chapter Private Extensions of the AtlasRep Package. Finally, the low level part of the interface are described in Chapter Technicalities of the AtlasRep Package.

As stated in The GAP Interface to the Atlas of Group Representations, the user interface is preliminary. It will be extended when the GAP version of the ATLAS of Group Representations is connected to other GAP databases such as the libraries of character tables and tables of marks.

For some of the examples in this chapter, the GAP packages `ctbllib` and `tomlib` are needed.

    gap> LoadPackage( "ctbllib" );
    true
    gap> LoadPackage( "tomlib" );
    true

## 2.1 Accessing vs. Constructing Representations

Note that accessing the data means in particular that it is not the aim of this package to construct representations from known ones. For example, if at least one permutation representation for a group G is stored but no matrix representation in a positive characteristic p then `OneAtlasGeneratingSetInfo` (see OneAtlasGeneratingSetInfo) returns `fail` when it is asked for a description of an available set of matrix generators for G in characteristic p, although such a representation can be obtained by reduction modulo p of an integral matrix representation, which in turn can be constructed from any permutation representation.

## 2.2 Group Names Used in the AtlasRep Package

The AtlasRep package refers to data of the ATLAS of group representations by the name of the group in question plus additional information. Thus it is essential to know this name, which is called the GAP name of the group in the following.

For an almost simple group, the GAP name is equal to the `Identifier` value (see Identifier!for character tables in the GAP Reference Manual) of the character table of this group in the GAP library (see ctbllib:Access to Library Character Tables in the documentation of the GAP Character Table Library); this name is usually very similar to the name used in the ATLAS of Finite Groups (CCN85), for example, `"M22"` is the GAP name of the Mathieu group M22, and `"12_1.U4(3).2_1"` is the GAP name of 121.U4(3).21.

Internally, for example as part of filenames (see Filenames Used in the Atlas of Group Representations), the package uses names that may differ from the GAP names; these names are called ATLAS-file names. For example, `A5`, `TE62`, and `F24` are possible values for groupname. Only `A5` is also a GAP name, but the other two are not; the corresponding GAP names are `2E6(2)` and `Fi24'`, respectively.

## 2.3 Standard Generators Used in the AtlasRep Package

For the general definition of standard generators of a group, see Standard Generators of Groups in the GAP Reference Manual; details can be found in Wil96.

Several different standard generators may be defined for a group, the definitions can be found at http://web.mat.bham.ac.uk/atlas/v2.0

When one specifies the standardization, the i-th set of standard generators is denoted by the number i. Note that when more than one set of standard generators is defined for a group, one must be careful to use compatible standardization. For example, the straight line programs in the database refer to a specific standardization of their inputs. That is, a straight line program for computing generators of a certain subgroup of a group G is defined only for a specific set of standard generators of G, and applying the program to matrix or permutation generators of G but w.r.t. a different standardization may yield unpredictable results. Therefore the results returned by the functions described in this chapter contain information about the standardizations they refer to.

## 2.4 Class Names Used in the AtlasRep Package

For each straight line program (see AtlasStraightLineProgram) that is used to compute lists of class representatives, it is essential to describe the classes in which these elements lie. Therefore, in these cases the records returned by the function `AtlasStraightLineProgram` (see AtlasStraightLineProgram) contain a component `outputs` with value a list of class names. Currently we define these class names only for almost simple groups, that is, subgroups of the automorphism groups of simple groups.

For the definition of class names of an almost simple group, we assume that the ordinary character tables of all nontrivial normal subgroups are shown in the ATLAS of Finite Groups CCN85.

Each class name is a string consisting of the element order of the class in question followed by a combination of capital letters, digits, and the characters `'` and `-` (starting with a capital letter). For example, `1A`, `12A1`, and `3B'` denote the class that contains the identity element, a class of element order 12, and a class of element order 3, respectively.

1.
  For the table of a simple group, the class names are the same as returned by the two argument version of the GAP function `ClassNames` (see ClassNames in the GAP Reference Manual), see Chapter 7, Section 5 of the ATLAS of Finite Groups CCN85: The classes are arranged w.r.t. increasing element order and for each element order w.r.t. decreasing centralizer order, the conjugacy classes that contain elements of order n are named nA, nB, nC, ¼; the alphabet used here is potentially infinite, and reads `A`, `B`, `C`, ¼, `Z`, `A1`, `B1`, ¼, `A2`, `B2`, ¼.

  For example, the classes of the alternating group A5 have the names `1A`, `2A`, `3A`, `5A`, and `5B`.

2.
  Next we consider the case of an upward extension G.A of a simple group G by a cyclic group of order A. The ATLAS defines class names for each element g of G.A only w.r.t. the group G.a, say, that is generated by G and g; namely, there is a power of g (with the exponent coprime to the order of g) for which the class has a name of the same form as the class names for simple groups, and the name of the class of g w.r.t. G.a is then obtained from this name by appending a suitable number of dashes `'`. So dashed class names refer exactly to those classes that are not printed in the ATLAS.

  For example, those classes of the symmetric group S5 that do not lie in A5 have the names `2B`, `4A`, and `6A`. The outer classes of the group L2(8).3 have the names `3B`, `6A`, `9D`, and `3B'`, `6A'`, `9D'`. and the outer elements of order 5 in the group Sz(32).5 lie in the classes with names `5B`, `5B'`, `5B''`, and `5B'''`.

  In the group G.A, the class of g may fuse with other classes. The name of the class of g in G.A is obtained from the names of the involved classes of G.a by concatenating their names after removing the element order part for all of them except the first one.

  For example, the elements of order 9 in the group L2(27).6 are contained in the subgroup L2(27).3 but not in L2(27). In L2(27).3, they lie in the classes `9A`, `9A'`, `9B`, and `9B'`; in L2(27).6, these classes fuse to `9AB` and `9A'B'`.

3.
  Now we define class names for general upward extensions G.A of a simple group G. Each element g of such a group lies in an upward extension G.a by a cyclic group, and the class names w.r.t. G.a are already defined. The name of the class of g in G.A is obtained by concatenating the names of the classes in the orbit of G.A on the classes of cyclic upward extensions of G, after ordering the names lexicographically and removing the element order part for all of them except the first one. An exception is the situation where dashed and non-dashed class names appear in an orbit; in this case, the dashed names are omitted.

  For example, the classes `21A` and `21B` of the group U3(5).3 fuse in U3(5).S3 to the class `21AB`, and the class `2B` of U3(5).2 fuses with the involution classes `2B'`, `2B''` in the groups U3(5).2¢ and U3(5).2¢¢ to the class `2B` of U3(5).S3.

  It may happen that some names in the `outputs` component of a record returned by `AtlasStraightLineProgram` (see AtlasStraightLineProgram) do not uniquely determine the classes of the corresponding elements. For example, the (algebraically conjugate) classes `39A` and `39B` of the group Co1 have not been distinguished yet. In such cases, the names used contain a minus sign `-`, and mean ``one of the classes in the range described by the name before and the name after the minus sign''; the element order part of the name does not appear after the minus sign. So the name `39A-B` for the group Co1 means `39A` or `39B`, and the name `20A-B'''` for the group Sz(32) means one of the (outer) classes of element order 20 in this group.

4.
  For a central downward extension m.G of a simple group G by a cyclic group of order m, let p denote the natural epimorphism from m.G onto G. Each class name of m.G has the form `nX_0`, `nX_1` etc., where `nX` is the class name of the image under p, and the indices `0`, `1` etc. are chosen according to the position of the class in the lifting order rows for G (see Chapter 7, Section 7 and the example in Section 8 of CCN85). For example, if m = 6 then `1A_1` and `1A_5` denote the classes containing the generators of the kernel of p, that is, central elements of order 6.

- `AtlasClassNames(` tbl`) F`

  If tbl is the ordinary character table of an almost simple group G whose ordinary character table is contained in the ATLAS of Finite Groups then `AtlasClassNames` returns the list of class names for G, as defined above. The ordering of class names is the same as the ordering of the columns of tbl.

  (The function may work also for almost simple non-ATLAS groups, but then clearly the class names returned are somewhat arbitrary.)

      gap> AtlasClassNames( CharacterTable( "L3(4).3" ) );
      [ "1A", "2A", "3A", "4ABC", "5A", "5B", "7A", "7B", "3B", "3B'", "3C", "3C'",
        "6B", "6B'", "15A", "15A'", "15B", "15B'", "21A", "21A'", "21B", "21B'" ]
      gap> AtlasClassNames( CharacterTable( "U3(5).2" ) );
      [ "1A", "2A", "3A", "4A", "5A", "5B", "5CD", "6A", "7AB", "8AB", "10A", "2B",
        "4B", "6D", "8C", "10B", "12B", "20A", "20B" ]
      gap> AtlasClassNames( CharacterTable( "L2(27).6" ) );
      [ "1A", "2A", "3AB", "7ABC", "13ABC", "13DEF", "14ABC", "2B", "4A", "26ABC",
        "26DEF", "28ABC", "28DEF", "3C", "3C'", "6A", "6A'", "9AB", "9A'B'", "6B",
        "6B'", "12A", "12A'" ]
      gap> AtlasClassNames( CharacterTable( "L3(4).3.2_2" ) );
      [ "1A", "2A", "3A", "4ABC", "5AB", "7A", "7B", "3B", "3C", "6B", "15A",
        "15B", "21A", "21B", "2C", "4E", "6E", "8D", "14A", "14B" ]
      gap> AtlasClassNames( CharacterTable( "3.A6" ) );
      [ "1A_0", "1A_1", "1A_2", "2A_0", "2A_1", "2A_2", "3A_0", "3B_0", "4A_0",
        "4A_1", "4A_2", "5A_0", "5A_1", "5A_2", "5B_0", "5B_1", "5B_2" ]

  ## 2.5 Accessing Data of the AtlasRep Package

  (Note that the output of the examples in this section refers to a perhaps outdated table of contents; the current version of the database may contain more information than is shown here.)

- `DisplayAtlasInfo( ) F`
- `DisplayAtlasInfo(` listofnames`) F`
- `DisplayAtlasInfo(` gapname`[,` std`] ) F`
- `DisplayAtlasInfo(` gapname`[,` std`], IsPermGroup[, true] ) F`
- `DisplayAtlasInfo(` gapname`[,` std`], NrMovedPoints,` n`) F`
- `DisplayAtlasInfo(` gapname`[,` std`], IsMatrixGroup[, true] ) F`
- `DisplayAtlasInfo(` gapname`[,` std`][, Characteristic,` p`][, Dimension,` n`] ) F`
- `DisplayAtlasInfo(` gapname`[,` std`], IsStraightLineProgram ) F`

  `DisplayAtlasInfo` lists the information available via the AtlasRep package, for the given inputs. Depending on the value of the `remote` component of the global variable `AtlasOfGroupRepresentationsInfo` (see AtlasOfGroupRepresentationsInfo), all the data provided by the ATLAS of Group Representations or only that in the local installation is available.

  Called without arguments, `DisplayAtlasInfo` prints an overview what information the ATLAS of Group Representations provides. One line is printed for each group G, with the following columns.

  `group`
    the GAP name of G (see Group Names Used in the AtlasRep Package),

  `#`
    the number of representations stored for G,

  `maxes`
    the available straight line programsindexstraight line program for computing generators of maximal subgroups of G,

  `cl`
    a `+` sign if at least one program for computing representatives of conjugacy classes of elements of G is stored, and a `-` sign otherwise,

  `cyc`
    a `+` sign if at least one program for computing representatives of classes of maximally cyclic subgroups of G is stored, and a `-` sign otherwise, and

  `out`
    descriptions of outer automorphisms of G for which at least one program is stored.

  In the second form, listofnames must be a list of strings that are GAP names for a group from the ATLAS of Group Representations; in this case, the overview described above is restricted to the groups in this list.

  In the third form, gapname must be a string that is a GAP name for a group from the ATLAS of Group Representations; in this case, `DisplayAtlasInfo` prints an overview of the information that is available for this group. One line is printed for each representation, showing the number of this representation (which is used in calls of `AtlasGenerators`, see AtlasGenerators), and a string of one of the following forms. `G <= Sym(`n``id`)` denotes a permutation representation of degree n, and `G <= GL(`n``id`,`descr`)` denotes a matrix representation of dimension n over a coefficient ring described by descr; in both cases, id is a (possibly empty) string specifying the representation, for example `G <= Sym(40a)` and `G <= Sym(40b)` denote two (nonequivalent) representations of degree 40. In the case of matrix representations, descr can be a prime power, `Z` (denoting the ring of integers), a description of an algebraic extension field, `C` (denoting an unspecified algebraic extension field), or `Z/`m `Z` for an integer m (denoting the ring of residues mod m); for example, `G <= GL(2a,4)` and `G <= GL(2b,4)` denote two (nonequivalent) representations of dimension 2 over the field with four elements. After the representations, the straight line programs available for gapname are listed.

  If the first argument is a string gapname, the following optional arguments can be used to restrict the overview.

  std
    must be a positive integer or a list of positive integers; if it is given then only those representations are considered that refer to the std-th set of standard generators or the i-th set of standard generators, for i in std (see Standard Generators Used in the AtlasRep Package),

  `IsPermGroup`
    restricts to permutation representations,

  `NrMovedPoints` and n
    for a positive integer or a list n, restrict to permutation representations of degree n or in the list n,

  `IsMatrixGroup`
    restricts to matrix representations,

  `Characteristic` and p
    for a prime integer or a list p, restrict to matrix representations over fields of characteristic p or in the list p (representations over residue class rings that are not fields can be addressed by ``p`= fail`),

  `Dimension` and n
    for a positive integer n or a list n, restrict to matrix representations of dimension n or in the list n, and

  `IsStraightLineProgram`
    restricts to straight line programs.

  The representations are ordered as follows. Permutation representations come first (ordered according to their degrees), followed by matrix representations over finite fields (ordered first according to the characteristic and second according to the dimension), matrix representations over the integers, and then matrix representations over algebraic extension fields (both kinds ordered according to the dimension), the last representations are matrix representations over residue class rings (ordered first according to the modulus and second according to the dimension).

  The maximal subgroups are ordered according to decreasing group order. For an extension G.p of a simple group G by an outer automorphism of prime order, this means that G is the first maximal subgroup and then come the extensions of the maximal subgroups of G and the novelties; so the n-th maximal subgroup of G and the n-th maximal subgroup of G.p are in general not related. (This coincides with the numbering used for the `Maxes` attribute for character tables, cf. ctbllib:Maxes in the documentation of the GAP Character Table Library.)

  Note that in each case, either the whole contents of the database or the contents of the local installation is considered, depending on whether the value of `AtlasOfGroupRepresentationsInfo.remote` is `true` or `false` (see AtlasOfGroupRepresentationsInfo).

      gap> DisplayAtlasInfo( [ "M11", "A5" ] );
      group     #  maxes  cl  cyc  out
      --------------------------------
      M11      42   1..5   +    +
      A5       18   1..3   -    -

  The above output means that the ATLAS of Group Representations contains 42 representations of the Mathieu group M11, straight line programs for computing generators of representatives of all five classes of maximal subgroups, for computing representatives of the conjugacy classes of elements and of generators of maximally cyclic subgroups, and contains no straight line program for applying outer automorphisms (well, in fact M11 admits no nontrivial outer automorphism). Analogously, 18 representations of the alternating group A5 are available, straight line programs for computing generators of representatives of all three classes of maximal subgroups, and no straight line programs for computing representatives of the conjugacy classes of elements, of generators of maximally cyclic subgroups, and no for computing images under outer automorphisms.

      gap> DisplayAtlasInfo( "A5", IsPermGroup );
      Representations for G = A5:    (all refer to std. generators 1)
      ---------------------------
      1: G <= Sym(5)
      2: G <= Sym(6)
      3: G <= Sym(10)
      gap> DisplayAtlasInfo( "A5", NrMovedPoints, [ 4 .. 9 ] );
      Representations for G = A5:    (all refer to std. generators 1)
      ---------------------------
      1: G <= Sym(5)
      2: G <= Sym(6)

  The first three representations stored for A5 are (in fact primitive) permutation representations.

      gap> DisplayAtlasInfo( "A5", Dimension, [ 1 .. 3 ] );
      Representations for G = A5:    (all refer to std. generators 1)
      ---------------------------
       8: G <= GL(2a,4)
       9: G <= GL(2b,4)
      10: G <= GL(3,5)
      12: G <= GL(3a,9)
      13: G <= GL(3b,9)
      17: G <= GL(3a,Field([Sqrt(5)]))
      18: G <= GL(3b,Field([Sqrt(5)]))
      gap> DisplayAtlasInfo( "A5", Characteristic, 0 );
      Representations for G = A5:    (all refer to std. generators 1)
      ---------------------------
      14: G <= GL(4,Z)
      15: G <= GL(5,Z)
      16: G <= GL(6,Z)
      17: G <= GL(3a,Field([Sqrt(5)]))
      18: G <= GL(3b,Field([Sqrt(5)]))

  The representations with number between 4 and 13 are (in fact irreducible) matrix representations over various finite fields, those with numbers 14 to 16 are integral matrix representations, and the last two are matrix representations over the field generated by Ö5 over the rational number field.

      gap> DisplayAtlasInfo( "A5", IsStraightLineProgram );
      Straight line programs for G = A5:    (all refer to std. generators 1)
      ----------------------------------
      available maxes of G:  [ 1 .. 3 ]

  Straight line programs are available to compute generators of representatives of the three classes of maximal subgroups of A5, see AtlasStraightLineProgram.

- `AtlasGenerators(` gapname`,` repnr`) F`
- `AtlasGenerators(` gapname`,` repnr`,` maxnr`) F`
- `AtlasGenerators(` identifier`) F`

  In the first two forms, gapname must be a string denoting a GAP name (see Group Names Used in the AtlasRep Package) of a group, and repnr a positive integer. If the ATLAS of Group Representations contains at least repnr representations for the group with GAP name gapname then `AtlasGenerators`, when called with gapname and repnr, returns an immutable record describing the repnr-th representation; otherwise `fail` is returned. If a third argument maxnr, a positive integer, is given then an immutable record describing the restriction of the repnr-th representation to the maxnr-th maximal subgroup is returned.

  The result record has the following components.

  `generators`
    a list of generators for the group,

  `standardization`
    the positive integer denoting the underlying standard generators,

  `identifier`
    a GAP object (a list of filenames plus additional information) that uniquely determines the representation; the value can be used as identifier argument of `AtlasGenerators` (see below).
  It should be noted that the number repnr refers to the number shown by `DisplayAtlasInfo` (see DisplayAtlasInfo) in the current session; it may be that after the addition of new representations, repnr refers to another representation.

  The third form of `AtlasGenerators`, with only argument identifier, can be used to fetch the result record with `identifier` value equal to identifier. The purpose of this variant is to access the same representation also in different GAP sessions.

      gap> gens1:= AtlasGenerators( "A5", 1 );
      rec( generators := [ (1,2)(3,4), (1,3,5) ], standardization := 1,
        identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
      gap> gens8:= AtlasGenerators( "A5", 8 );
      rec(
        generators := [ [ [ Z(2)^0, 0*Z(2) ], [ Z(2^2), Z(2)^0 ] ], [ [ 0*Z(2), Z(2
                       )^0 ], [ Z(2)^0, Z(2)^0 ] ] ], standardization := 1,
        identifier := [ "A5", [ "A5G1-f4r2aB0.m1", "A5G1-f4r2aB0.m2" ], 1, 4 ] )
      gap> gens17:= AtlasGenerators( "A5", 17 );
      rec(
        generators := [ [ [ -1, 0, 0 ], [ 0, -1, 0 ], [ -E(5)-E(5)^4, -E(5)-E(5)^4,
                    1 ] ], [ [ 0, 1, 0 ], [ 0, 0, 1 ], [ 1, 0, 0 ] ] ],
        standardization := 1, identifier := [ "A5", "A5G1-Ar3aB0.g", 1, 3 ] )

  Each of the above pairs of elements generates a group isomorphic to A5.

      gap> gens1max2:= AtlasGenerators( "A5", 1, 2 );
      rec( generators := [ (1,2)(3,4), (2,3)(4,5) ], standardization := 1,
        identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5, 2 ] )
      gap> id:= gens1max2.identifier;;
      gap> gens1max2 = AtlasGenerators( id );
      true
      gap> max2:= Group( gens1max2.generators );;
      gap> Size( max2 );
      10
      gap> IdGroup( max2 ) = IdGroup( DihedralGroup( 10 ) );
      true

  The elements stored in `gens1max2.generators` describe the restriction of the first representation of A5 to a group in the second class of maximal subgroups of A5 according to the list in the ATLAS of Finite Groups CCN85; this subgroup is isomorphic to the dihedral group D10.

- `AtlasStraightLineProgram(` gapname`[,` std`][, "maxes"],` maxnr`) F`
- `AtlasStraightLineProgram(` gapname`[,` std`], "classes" ) F`
- `AtlasStraightLineProgram(` gapname`[,` std`], "cyclic" ) F`
- `AtlasStraightLineProgram(` gapname`[,` std`], "automorphism",` autname`) F`
- `AtlasStraightLineProgram(` gapname`,` std`, "restandardize",` std2`) F`
- `AtlasStraightLineProgram(` gapname`[,` std`], "other",` descr`) F`
- `AtlasStraightLineProgram(` identifier`) F`

  In all forms except the last one, gapname must be a string denoting a GAP name (see Group Names Used in the AtlasRep Package) of a group G, say, and std a positive integer denoting the standard generators of G used (see Standard Generators Used in the AtlasRep Package). If the ATLAS of Group Representations contains a straight line program (see Straight Line Programs in the GAP Reference Manual) as described by the other arguments (see below) then `AtlasStraightLineProgram` returns an immutable record with this program, otherwise `fail` is returned.

  If the optional argument std is given, only those straight line programs are considered that take generators from the std-th set of standard generators of G as input.

  The result record has the following components.

  `program`
    the required straight line program,

  `standardization`
    the positive integer denoting the underlying standard generators of G,

  `identifier`
    a GAP object (a list of filenames plus additional information) that uniquely determines the program; the value can be used as identifier argument of `AtlasStraightLineProgram` (see below).

  In the first form, the last argument must be a positive integer maxnr, and the required program computes generators of the maxnr-th maximal subgroup of the group with GAP name gapname.

  If the last argument is one of the strings `"classes"` or `"cyclic"` then the required program computes representatives of conjugacy classes of elements or representatives of generators of maximally cyclic subgroups of G, respectively.

  See BSW01 and SWW00 for the background concerning these straight line programs. In the second and third form of `AtlasStraightLineProgram`, the result record also contains a component `outputs`, whose value is a list of class names of the outputs, as described in Section Class Names Used in the AtlasRep Package.

  If the last two arguments are `"automorphism"` and a string autname then the required program computes images of standard generators under the outer automorphism of G that is given by this string.

  If the last two arguments are `"restandardize"` and an integer std2 then the required program computes standard generators of G w.r.t. the std2-th set of standard generators of G.

  If the last two arguments are `"other"` and a string descr then the required program computes images of standard generators under the program that is described by this string. The last form of `AtlasStraightLineProgram`, with only argument identifier, can be used to fetch the result record with `identifier` value equal to identifier.

      gap> prog:= AtlasStraightLineProgram( "A5", 2 );
      rec( program := <straight line program>, standardization := 1,
        identifier := [ "A5", "A5G1-max2W1", 1 ] )
      gap> StringOfResultOfStraightLineProgram( prog.program, [ "a", "b" ] );
      "[ a, bbab ]"
      gap> gens1:= AtlasGenerators( "A5", 1 );
      rec( generators := [ (1,2)(3,4), (1,3,5) ], standardization := 1,
        identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
      gap> maxgens:= ResultOfStraightLineProgram( prog.program, gens1.generators );
      [ (1,2)(3,4), (2,3)(4,5) ]
      gap> maxgens = gens1max2.generators;
      true

  The above example shows that for restricting representations given by standard generators to a maximal subgroup of A5, we can also fetch and apply the appropriate straight line program. Such a program (see Straight Line Programs in the GAP Reference Manual) takes standard generators of a group --in this example A5-- as its input, and returns a list of elements in this group --in this example generators of the D10 subgroup we had met above-- which are computed essentially by evaluating structured words in terms of the standard generators.

      gap> prog:= AtlasStraightLineProgram( "J1", "cyclic" );
      rec( program := <straight line program>, standardization := 1,
        identifier := [ "J1", "J1G1-cycW1", 1 ],
        outputs := [ "6A", "7A", "10B", "11A", "15B", "19A" ] )
      gap> gens:= GeneratorsOfGroup( FreeGroup( "x", "y" ) );;
      gap> ResultOfStraightLineProgram( prog.program, gens );
      [ x*y*x*y^2*x*y*x*y^2*x*y*x*y*x*y^2*x*y^2, x*y, x*y*x*y^2*x*y*x*y*x*y^2*x*y^2,
        x*y*x*y*x*y^2*x*y^2*x*y*x*y^2*x*y*x*y*x*y^2*x*y^2*x*y*x*y^2*x*y*x*y*x*y^
          2*x*y^2, x*y*x*y*x*y^2*x*y^2, x*y*x*y^2 ]

  The above example shows how to fetch and use straight line programs for computing generators of representatives of maximally cyclic subgroups of a given group.

- `OneAtlasGeneratingSetInfo( [`gapname`][,` std`] ) F`
- `OneAtlasGeneratingSetInfo( [`gapname`][,` std`], IsPermGroup[, true] ) F`
- `OneAtlasGeneratingSetInfo( [`gapname`][,` std`], NrMovedPoints,` n`) F`
- `OneAtlasGeneratingSetInfo( [`gapname`][,` std`], IsMatrixGroup[, true] ) F`
- `OneAtlasGeneratingSetInfo( [`gapname`][,` std`][, Characteristic,` p`][, Dimension,` m`] ) F`
- `OneAtlasGeneratingSetInfo( [`gapname`][,` std`][, Ring,` R`][, Dimension,` m`] ) F`

  Let gapname be a string. If the ATLAS of Group Representations contains at least one representation for the group G with GAP name gapname and with the required properties then `OneAtlasGeneratingSetInfo` returns a record with the component `identifier` that corresponds to the records returned by `AtlasGenerators` (see AtlasGenerators), such that calling `AtlasGenerators` with the value of the `identifier` component of the result will fetch such a representation; otherwise `fail` is returned. If the argument std is given then it must be a positive integer or a list of positive integers, denoting the sets of standard generators w.r.t. which the representation shall be given (see Standard Generators Used in the AtlasRep Package).

  Note that `OneAtlasGeneratingSetInfo` does not attempt to transfer remote data files, just the known table of contents is evaluated. So this function (as well as `AllAtlasGeneratingSetInfos`) can be used to check for the availability of certain representations, and later one can fetch those one wants to work with via `AtlasGenerators`.

  In the first form, the result of `OneAtlasGeneratingSetInfo` describes the first generating set for G, in the ordering shown by `DisplayAtlasInfo` (see DisplayAtlasInfo). In the remaining forms, `IsPermGroup` and `IsMatrixGroup` restrict to permutation and matrix representations, respectively, `NrMovedPoints` restricts to permutation representations of degree equal to the integer n or in the list n, `Characteristic` restricts to matrix representations of characteristic equal to the integer p or in the list p (representations over arbitrary residue class rings that are not fields can be accessed with ``p`= fail`), `Dimension` restricts to matrix representations of dimension equal to the positive integer m or in the list m, and `Ring` restricts to matrix representations for which all matrix entries are contained in the ring R.

- `AllAtlasGeneratingSetInfos( [`gapname`][,` std`] ) F`
- `AllAtlasGeneratingSetInfos( [`gapname`][,` std`], IsPermGroup[, true] ) F`
- `AllAtlasGeneratingSetInfos( [`gapname`][,` std`], NrMovedPoints,` n`) F`
- `AllAtlasGeneratingSetInfos( [`gapname`][,` std`], IsMatrixGroup[, true] ) F`
- `AllAtlasGeneratingSetInfos( [`gapname`][,` std`][, Characteristic,` p`][, Dimension,` m`] ) F`
- `AllAtlasGeneratingSetInfos( [`gapname`][,` std`][, Ring,` R`][, Dimension,` m`] ) F`

  `AllAtlasGeneratingSetInfos` is similar to `OneAtlasGeneratingSetInfo` (see OneAtlasGeneratingSetInfo). The difference is that the list of all records with `identifier` components for the available representations with the given properties is returned instead of just one such component. In particular an empty list is returned if no such representation is available.

  Examples

  First we access a permutation representation for the alternating group A5.

      gap> info:= OneAtlasGeneratingSetInfo( "A5" );
      rec( identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
      gap> gens:= AtlasGenerators( info.identifier );
      rec( generators := [ (1,2)(3,4), (1,3,5) ], standardization := 1,
        identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] )
      gap> info = OneAtlasGeneratingSetInfo( "A5", IsPermGroup, true );
      true
      gap> info = OneAtlasGeneratingSetInfo( "A5", NrMovedPoints, [ 1 .. 10 ] );
      true
      gap> OneAtlasGeneratingSetInfo( "A5", NrMovedPoints, 20 );
      fail

  Note that a permutation representation of degree 20 could be obtained by taking twice the primitive representation on 10 points; however, the ATLAS of Group Representations does not store this imprimitive representation (cf. Accessing vs. Constructing Representations).

  Next we access matrix representations of A5.

      gap> info:= OneAtlasGeneratingSetInfo( "A5", IsMatrixGroup, true );
      rec( identifier := [ "A5", [ "A5G1-f2r4aB0.m1", "A5G1-f2r4aB0.m2" ], 1, 2 ] )
      gap> gens:= AtlasGenerators( info.identifier );
      rec(
        generators := [ <an immutable 4x4 matrix over GF2>, <an immutable 4x4 matrix\
       over GF2> ], standardization := 1,
        identifier := [ "A5", [ "A5G1-f2r4aB0.m1", "A5G1-f2r4aB0.m2" ], 1, 2 ] )
      gap> info = OneAtlasGeneratingSetInfo( "A5", Dimension, 4 );
      true
      gap> info = OneAtlasGeneratingSetInfo( "A5", Characteristic, 2 );
      true
      gap> OneAtlasGeneratingSetInfo( "A5", Characteristic, [2,5], Dimension, 2 );
      rec( identifier := [ "A5", [ "A5G1-f4r2aB0.m1", "A5G1-f4r2aB0.m2" ], 1, 4 ] )
      gap> OneAtlasGeneratingSetInfo( "A5", Characteristic, [2,5], Dimension, 1 );
      fail
      gap> info:= OneAtlasGeneratingSetInfo( "A5", Characteristic, 0, Dimension, 4 );
      rec( identifier := [ "A5", "A5G1-Zr4B0.g", 1, 4 ] )
      gap> gens:= AtlasGenerators( info.identifier );
      rec(
        generators := [ [ [ 1, 0, 0, 0 ], [ 0, 0, 1, 0 ], [ 0, 1, 0, 0 ], [ -1, -1,
                    -1, -1 ] ],
            [ [ 0, 1, 0, 0 ], [ 0, 0, 0, 1 ], [ 0, 0, 1, 0 ], [ 1, 0, 0, 0 ] ] ],
        standardization := 1, identifier := [ "A5", "A5G1-Zr4B0.g", 1, 4 ] )
      gap> info = OneAtlasGeneratingSetInfo( "A5", Ring, Integers );
      true
      gap> info = OneAtlasGeneratingSetInfo( "A5", Ring, CF(37) );
      true
      gap> OneAtlasGeneratingSetInfo( "A5", Ring, Integers mod 77 );
      fail
      gap> info:= OneAtlasGeneratingSetInfo( "A5", Ring, CF(5), Dimension, 3 );
      rec( identifier := [ "A5", "A5G1-Ar3aB0.g", 1, 3 ] )
      gap> gens:= AtlasGenerators( info.identifier );
      rec(
        generators := [ [ [ -1, 0, 0 ], [ 0, -1, 0 ], [ -E(5)-E(5)^4, -E(5)-E(5)^4,
                    1 ] ], [ [ 0, 1, 0 ], [ 0, 0, 1 ], [ 1, 0, 0 ] ] ],
        standardization := 1, identifier := [ "A5", "A5G1-Ar3aB0.g", 1, 3 ] )
      gap> OneAtlasGeneratingSetInfo( "A5", Ring, GF(17) );
      fail
      gap> AllAtlasGeneratingSetInfos( "A5", IsPermGroup, true );
      [ rec( identifier := [ "A5", [ "A5G1-p5B0.m1", "A5G1-p5B0.m2" ], 1, 5 ] ),
        rec( identifier := [ "A5", [ "A5G1-p6B0.m1", "A5G1-p6B0.m2" ], 1, 6 ] ),
        rec( identifier := [ "A5", [ "A5G1-p10B0.m1", "A5G1-p10B0.m2" ], 1, 10 ] ) ]

  Note that a matrix representation in any characteristic can be obtained by reducing a permutation representation or an integral matrix representation; however, the ATLAS of Group Representations does not store such a representation (cf. Accessing vs. Constructing Representations).

  ## 2.6 Updating the Tables of Contents of the AtlasRep Package

  The file `atlasprm.g` in the `gap` directory of the AtlasRep package contains the initial table of contents of the database. This file is read by default when the AtlasRep package is loaded. It may happen that new data files have been added to the servers since the last release of the AtlasRep package, thus it is useful to update the table of contents of the package from time to time.

  For that, one can either fetch the most recent version of the file `atlasprm.g` from the home page of the package (see Web Services for the AtlasRep Package) or use the functions described below for creating an updated version of this file oneself. The latter alternative works only if the perl module `libnet` is available (and `AtlasOfGroupRepresentationsInfo.wget` does not have the value `true`); the idea is to inspect the data currently available on the servers or in the local data directories with `ReloadAtlasTableOfContents` (which updates the table of contents within the GAP session), and then to write the new table of contents to a local file with `StoreAtlasTableOfContents`.

  The new file can be read into the GAP session via `ReplaceAtlasTableOfContents` (see ReplaceAtlasTableOfContents). Alternatively, one can add a line to the user's `.gaprc` file (see The .gaprc file in the GAP Reference Manual), which assigns the filename of the current `atlasprm.g` file (as an absolute path or relative to the user's home directory, cf. Directory in the GAP Reference Manual) to the global variable `ATLASREP_TOCFILE`; in this case, this file is read upon startup of GAP instead of the one from the package dirstribution. Note that reading such a file is much more efficient than calling `ReloadAtlasTableOfContents`.

  Users who have write access to the directory where the AtlasRep package is installed can alternatively use the `maketoc` script in the `etc` directory of the package for regularly updating the file `atlasprm.g`.

  Date and time of the last update of the table of contents are stored in its `lastupdated` component.

- `ReloadAtlasTableOfContents(` dirname`) F`

  Let dirname be a string, which must be `"local"`, `"remote"` or the name of a private data directory (see Chapter Private Extensions of the AtlasRep Package). `ReloadAtlasTableOfContents` replaces the table of contents of the AtlasRep package that is described by dirname by the one obtained from inspecting the actual contents of the data directories (see The Tables of Contents of the Atlas of Group Representations).

  The function returns `fail` if the required table of contents could not be reloaded, otherwise `true` is returned.

  If dirname is different from `"remote"` then `ReloadAtlasTableOfContents` needs the system program `ls`.

- `StoreAtlasTableOfContents(` filename`) F`

  Let filename be a string. `StoreAtlasTableOfContents` prints the loaded table of contents of the servers to the file with name filename.

- `ReplaceAtlasTableOfContents(` filename`) F`

  Let filename be the name of a file that has been created with `StoreAtlasTableOfContents` (see StoreAtlasTableOfContents).

  `ReplaceAtlasTableOfContents` first removes the information that GAP has stored about the table of contents of the servers, and then reads the file with name filename, thus replacing the previous information by the stored one.

  ## 2.7 Examples of Using the AtlasRep Package

  Example 1: Class Representatives

  First we show the computation of class representatives of the Mathieu group M11, in a 2-modular matrix representation. We start with the ordinary and Brauer character tables of this group.

      gap> tbl:= CharacterTable( "M11" );;
      gap> modtbl:= tbl mod 2;;
      gap> CharacterDegrees( modtbl );
      [ [ 1, 1 ], [ 10, 1 ], [ 16, 2 ], [ 44, 1 ] ]

  The output of `CharacterDegrees` (see CharacterDegrees in the GAP Reference Manual) means that the 2-modular irreducibles of M11 have degrees 1, 10, 16, 16, and 44.

  Using `DisplayAtlasInfo`, we find out that matrix generators for the irreducible 10-dimensional representation are available in the AtlasRep database.

      gap> DisplayAtlasInfo( "M11", Characteristic, 2 );
      Representations for G = M11:    (all refer to std. generators 1)
      ----------------------------
       6: G <= GL(10,2)
       7: G <= GL(32,2)
       8: G <= GL(44,2)
      16: G <= GL(16a,4)
      17: G <= GL(16b,4)

  So we decide to work with this representation. We fetch the generators and compute the list of class representatives of M11 in the representation. The ordering of class representatives is the same as that in the character table of the ATLAS of Finite Groups (CCN85), which coincides with the ordering of columns in the GAP table we have fetched above.

      gap> info:= OneAtlasGeneratingSetInfo( "M11", Characteristic, 2,
      >                                             Dimension, 10 );;
      gap> gens:= AtlasGenerators( info.identifier );;
      gap> ccls:= AtlasStraightLineProgram( "M11", gens.standardization,
      >                                     "classes" );
      rec( program := <straight line program>, standardization := 1,
        identifier := [ "M11", "M11G1-cclsW1", 1 ],
        outputs := [ "1A", "2A", "3A", "4A", "5A", "6A", "8A", "8B", "11A", "11B" ]
       )
      gap> reps:= ResultOfStraightLineProgram( ccls.program, gens.generators );;

  Let us check that the class representatives have the right orders.

      gap> Length( reps );
      10
      gap> List( reps, Order ) = OrdersClassRepresentatives( tbl );
      true

  From the class representatives, we can compute the Brauer character we had started with. This Brauer character is defined on all classes of the 2-modular table. So we first pick only those representatives, using the GAP function `GetFusionMap` (see GetFusionMap in the GAP Reference Manual); in this situation, it returns the class fusion from the Brauer table into the ordinary table.

      gap> fus:= GetFusionMap( modtbl, tbl );
      [ 1, 3, 5, 9, 10 ]
      gap> modreps:= reps{ fus };;

  Then we call the GAP function `BrauerCharacterValue` (see BrauerCharacterValue in the GAP Reference Manual), which computes the Brauer character value from the matrix given.

      gap> char:= List( modreps, BrauerCharacterValue );
      [ 10, 1, 0, -1, -1 ]
      gap> Position( Irr( modtbl ), char );
      2

  Example 2: Permutation and Matrix Representations

  The second example shows the computation of a permutation representation from a matrix representation. We work with the 10-dimensional representation used above, and consider the action on the 210 vectors of the underlying row space.

      gap> grp:= Group( gens.generators );;
      gap> v:= GF(2)^10;;
      gap> orbs:= Orbits( grp, AsList( v ) );;
      gap> List( orbs, Length );
      [ 1, 396, 55, 330, 66, 165, 11 ]

  We see that there are six nontrivial orbits, and we can compute the permutation actions on these orbits directly using `Action`. However, for larger examples, one cannot write down all orbits on the row space, so one has to use another strategy if one is interested in a particular orbit.

  Let us assume that we are interested in the orbit of length 11. The point stabilizer is the first maximal subgroup of M11, thus the restriction of the representation to this subgroup has a nontrivial fixed point space. This restriction can be computed using the AtlasRep package.

      gap> gens:= AtlasGenerators( "M11", 6, 1 );;

  Now computing the fixed point space is standard linear algebra.

      gap> id:= IdentityMat( 10, GF(2) );;
      gap> sub1:= Subspace( v, NullspaceMat( gens.generators[1] - id ) );;
      gap> sub2:= Subspace( v, NullspaceMat( gens.generators[2] - id ) );;
      gap> fix:= Intersection( sub1, sub2 );
      <vector space of dimension 1 over GF(2)>

  The final step is of course the computation of the permutation action on the orbit.

      gap> orb:= Orbit( grp, Basis( fix )[1] );;
      gap> act:= Action( grp, orb );;  Print( act, "\n" );
      Group( [ ( 1, 2)( 4, 6)( 5, 8)( 7,10), ( 1, 3, 5, 9)( 2, 4, 7,11) ] )

  Note that this group is not equal to the group obtained by fetching the permutation representation from the database. This is due to a different numbering of the points, so the groups are permutation isomorphic.

      gap> permgrp:= Group( AtlasGenerators( "M11", 1 ).generators );;
      gap> Print( permgrp, "\n" );
      Group( [ ( 2,10)( 4,11)( 5, 7)( 8, 9), ( 1, 4, 3, 8)( 2, 5, 6, 9) ] )
      gap> permgrp = act;
      false
      gap> IsConjugate( SymmetricGroup(11), permgrp, act );
      true

  Example 3: Outer Automorphisms

  The straight line programs for applying outer automorphisms to standard generators can of course be used to define the automorphisms themselves as GAP mappings.

      gap> DisplayAtlasInfo( "G2(3)", IsStraightLineProgram );
      Straight line programs for G = G2(3):    (all refer to std. generators 1)
      -------------------------------------
      available maxes of G:  [ 1 .. 10 ]
      class repres. of G available
      repres. of cyclic subgroups of G available
      available automorphisms:  [ "2" ]
      gap> prog:= AtlasStraightLineProgram( "G2(3)", "automorphism", "2" ).program;;
      gap> gens:= AtlasGenerators( "G2(3)", 1 ).generators;;
      gap> imgs:= ResultOfStraightLineProgram( prog, gens );;

  If we are not suspicious whether the script really describes an automorphism then we should tell this to GAP, in order to avoid the expensive checks of the properties of being a homomorphism and bijective (see Creating Group Homomorphisms in the GAP Reference Manual). This looks as follows.

      gap> g:= Group( gens );;
      gap> aut:= GroupHomomorphismByImagesNC( g, g, gens, imgs );;
      gap> SetIsBijective( aut, true );

  If we are suspicious whether the script describes an automorphism then we might have the idea to check it with GAP, as follows.

      gap> aut:= GroupHomomorphismByImages( g, g, gens, imgs );;
      gap> IsBijective( aut );
      true

  (Note that even for a comparatively small group such as G2(3), this was a difficult task for GAP before version 4.3.)

  Often one can form images under an automorphism a, say, without creating the homomorphism object. This is obvious for the standard generators of the group G themselves, but also for generators of a maximal subgroup M computed from standard generators of G, provided that the straight line programs in question refer to the same standard generators. Note that the generators of M are given by evaluating words in terms of standard generators of G, and their images under a can be obtained by evaluating the same words at the images under a of the standard generators of G.

      gap> max1:= AtlasStraightLineProgram( "G2(3)", 1 ).program;;
      gap> mgens:= ResultOfStraightLineProgram( max1, gens );;
      gap> comp:= CompositionOfStraightLinePrograms( max1, prog );;
      gap> mimgs:= ResultOfStraightLineProgram( comp, gens );;

  The list `mgens` is the list of generators of the first maximal subgroup of G2(3), `mimgs` is the list of images under the automorphism given by the straight line program `prog`. Note that applying the program returned by `CompositionOfStraightLinePrograms` means to apply first `prog` and then `max1`, see CompositionOfStraightLinePrograms in the GAP Reference Manual.

  Since we have already constructed the GAP object representing the automorphism, we can check whether the results are equal.

      gap> mimgs = List( mgens, x -> x^aut );
      true

  However, it should be emphasized that using `aut` requires a huge machinery of computations behind the scenes, whereas applying the straight line programs `prog` and `max1` involves only elementary operations with the generators. The latter is feasible also for larger groups, for which constructing the GAP automorphism might be impossible.

  Example 4: Using the GAP Library of Tables of Marks

  The GAP library of tables of marks provides, for many almost simple groups, information for constructing representatives of all conjugacy classes of subgroups. If this information is compatible with the standard generators of the ATLAS of Group Representations then we can use it to restrict any representation from the ATLAS to prescribed subgroups. This is useful in particular for those subgroups for which the ATLAS of Group Representations itself does not contain a straight line program.

      gap> tom:= TableOfMarks( "A5" );
      TableOfMarks( "A5" )
      gap> info:= StandardGeneratorsInfo( tom );
      [ rec( generators := "a, b", description := "|a|=2, |b|=3, |ab|=5",
            script := [ [ 1, 2 ], [ 2, 3 ], [ 1, 1, 2, 1, 5 ] ], ATLAS := true ) ]

  The `true` value of the component `ATLAS` indicates that the information stored on `tom` refers to the standard generators of type 1 in the ATLAS of Group Representations.

  We want to restrict a 4-dimensional integral representation of A5 to a Sylow 2 subgroup of A5, and use `RepresentativeTomByGeneratorsNC` (see RepresentativeTomByGeneratorsNC in the GAP Reference Manual) for that.

      gap> info:= OneAtlasGeneratingSetInfo( "A5", Ring, Integers, Dimension, 4 );;
      gap> stdgens:= AtlasGenerators( info.identifier );
      rec(
        generators := [ [ [ 1, 0, 0, 0 ], [ 0, 0, 1, 0 ], [ 0, 1, 0, 0 ], [ -1, -1,
                    -1, -1 ] ],
            [ [ 0, 1, 0, 0 ], [ 0, 0, 0, 1 ], [ 0, 0, 1, 0 ], [ 1, 0, 0, 0 ] ] ],
        standardization := 1, identifier := [ "A5", "A5G1-Zr4B0.g", 1, 4 ] )
      gap> orders:= OrdersTom( tom );
      [ 1, 2, 3, 4, 5, 6, 10, 12, 60 ]
      gap> pos:= Position( orders, 4 );
      4
      gap> sub:= RepresentativeTomByGeneratorsNC( tom, pos, stdgens.generators );
      <matrix group of size 4 with 2 generators>
      gap> GeneratorsOfGroup( sub );
      [ [ [ 1, 0, 0, 0 ], [ -1, -1, -1, -1 ], [ 0, 0, 0, 1 ], [ 0, 0, 1, 0 ] ],
        [ [ 1, 0, 0, 0 ], [ 0, 0, 1, 0 ], [ 0, 1, 0, 0 ], [ -1, -1, -1, -1 ] ] ]

  [Up] [Previous] [Next] [Index]