WindowTitle {Desktop}
WindowSize 360 400		# Taille
WindowPosition 191 50		# Position
ForeColor	{black}
BackColor	{grey85}
ShadowColor	{grey55}
HilightColor	{grey100}
Font		-adobe-helvetica-bold-r-*-*-12-*

Init
 Begin
  WarpPointer 1
  Set $RAISE=(GetASoption {cat ~/.steprc} {FvwmAuto} 0)
  If $RAISE=={KillModule Auto} Then
   ChangeValue 6 0
  Else
   ChangeValue 6 1

  Set $FOCUS=(GetASoption {cat ~/.steprc} {ChangeDefaultFocus} 0)
  If $FOCUS=={ChangeDefaultFocus SloppyFocus} Then
   ChangeValue 8 1
  If $FOCUS=={ChangeDefaultFocus ClickToFocus} Then
   ChangeValue 8 2
  If $FOCUS=={ChangeDefaultFocus FocusFollowsMouse} Then
   ChangeValue 8 3

  Set $PAGE=(GetASoption {cat ~/.steprc} {EdgeScroll} 0)
  If $PAGE == {EdgeScroll 100 100} Then
   ChangeValue 12 1
  If $PAGE == {EdgeScroll 0 0} Then
   ChangeValue 12 2
  If $PAGE == {EdgeScroll 100 0} Then
   ChangeValue 12 3
  If $PAGE == {EdgeScroll 0 100} Then
   ChangeValue 12 4
  If $PAGE == {EdgeScroll 50 50} Then
   ChangeValue 12 5
  If $PAGE == {EdgeScroll 100000 100000} Then
   ChangeValue 12 6

  Set $COLOR=(GetASoption {cat ~/.steprc} {ColormapFocus} 0)
  If $COLOR=={ColormapFocus FollowsMouse} Then
   ChangeValue 10 1
  Else
   ChangeValue 10 2

  Set $NBROW=(GetASoption {cat ~/.steprc} {DeskTopSize} 3)
  Set $NBCOL=(GetASoption {cat ~/.steprc} {DeskTopSize} 2)
  ChangeTitle 21 $NBROW
  ChangeTitle 20 $NBCOL
  ChangeValue 19 $NBROW
  ChangeValue 18 $NBCOL

  Set $OPAQ=(GetASoption {cat ~/.steprc} {OpaqueMoveSize} 2)
  ChangeValue 23 $OPAQ
  ChangeTitle 25 $OPAQ

 End
 
Widget 1
Property
 Size 50 30
 Position 100 340
 Type PushButton
 Title {OK}
Main
 Case message of
  SingleClic :
  Begin
   Do $RAISE
   WriteToFile .steprc $RAISE

   Do $FOCUS
   WriteToFile .steprc $FOCUS

   Do $PAGE
   WriteToFile .steprc $PAGE

   Do $COLOR
   WriteToFile .steprc $COLOR

   Do {OpaqueMoveSize } (GetValue 23)
   WriteToFile .steprc {OpaqueMoveSize } (GetValue 23)

   Do {DeskTopSize } (GetValue 18) { } (GetValue 19)
   WriteToFile .steprc {DeskTopSize } (GetValue 18) { } (GetValue 19)

   Quit
  End
End

Widget 2
Property
 Size 50 30
 Position 190 340
 Type PushButton
 Title {Apply}
Main
 Case message of
  SingleClic :
  Begin
   Do $RAISE
   Do $FOCUS
   Do $PAGE
   Do $COLOR
   Do {DeskTopSize } (GetValue 18) { } (GetValue 19)
   Do {OpaqueMoveSize } (GetValue 23)
  End
End

Widget 3
Property
 Size 30 30
 Position 280 340
 Type PushButton
 Title {Cancel}
Main
 Case message of
  SingleClic :
  Begin
   Quit
  End
End

Widget 4
Property
 Size 340 310
 Position 10 10
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 5
Property
 Position 30 40
 Type ItemDraw
 Title {Auto raise:}
Main
 Case message of
  SingleClic :
  Begin
  End
End


Widget 6
Property
 Position 110 40
 Type CheckBox
 Title {On}
Main
 Case message of
  SingleClic :
  Begin
   If (GetValue 6) == 1 Then
    Set $RAISE={Module FvwmAuto 2000 Raise Nop}
   Else
    Set $RAISE={KillModule FvwmAuto}
  End
End

Widget 7
Property
 Position 30 75
 Type ItemDraw
 Title {Focus:}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 8
Property
 Position 110 70
 Type PopupMenu
 Title {Sloppy Focus|Click To Focus|Focus Follows Mouse}
Main
 Case message of
  SingleClic :
  Begin
   If (GetValue 8) == 1 Then
    Set $FOCUS={ChangeDefaultFocus SloppyFocus}
   If (GetValue 8) == 2 Then
    Set $FOCUS={ChangeDefaultFocus ClickToFocus}
   If (GetValue 8) == 3 Then
    Set $FOCUS={ChangeDefaultFocus FocusFollowsMouse}
  End
End

Widget 11
Property
 Position 30 155
 Type ItemDraw
 Title {Paging:}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 12
Property
 Position 110 150
 Type PopupMenu
 Title {Full Paging ON|All Paging OFF|Horizontal Paging Only|Vertical Paging Only|Partial Paging|Full Paging && Edge Wrap}
Main
 Case message of
  SingleClic :
  Begin
   If (GetValue 12) == 1 Then
    Set $PAGE={EdgeScroll 100 100}
   If (GetValue 12) == 2 Then
    Set $PAGE={EdgeScroll 0 0}
   If (GetValue 12) == 3 Then
    Set $PAGE={EdgeScroll 100 0}
   If (GetValue 12) == 4 Then
    Set $PAGE={EdgeScroll 0 100}
   If (GetValue 12) == 5 Then
    Set $PAGE={EdgeScroll 50 50}
   If (GetValue 12) == 6 Then
    Set $PAGE={EdgeScroll 100000 100000}
  End
End

Widget 9
Property
 Position 30 115
 Type ItemDraw
 Title {Colormap:}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 10
Property
 Position 110 110
 Type PopupMenu
 Title {Colormap Follows Mouse|Colormap Follows Focus}
Main
 Case message of
  SingleClic :
  Begin
   If (GetValue 10) == 1 Then
    Set $COLOR={ColormapFocus FollowsMouse}
   Else
    Set $COLOR={ColormapFocus FollowsFocus}
  End
End

Widget 13
Property
 Position 30 210
 Type ItemDraw
 Title {Desktop size}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 14
Property
 Position 120 195
 Type ItemDraw
 Title {Nb of column:}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 15
Property
 Position 139 228
 Type ItemDraw
 Title {Nb of row:}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 16
Property
 Size 25 25
 Position 210 190
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 17
Property
 Size 25 25
 Position 210 225
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 18
Property
 Size 25 25
 Position 240 187
 Value 1
 MaxValue 9
 MinValue 1
 Type MiniScroll
Main
 Case message of
  SingleClic :
  Begin
   ChangeTitle 20 (GetValue 18)
  End
End

Widget 19
Property
 Size 25 25
 Position 240 222
 Type MiniScroll
 Value 1
 MaxValue 9
 MinValue 1
Main
 Case message of
  SingleClic :
  Begin
   ChangeTitle 21 (GetValue 19)
  End
End

Widget 20
Property
 Position 218 195
 Type ItemDraw
 Title {4}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 21
Property
 Position 218 228
 Type ItemDraw
 Title {2}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 22
Property
 Size 35 25
 Position 200 272
 Type Rectangle
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 23
Property
 Size 25 25
 Position 240 268
 Value 100
 MaxValue 100
 MinValue 0
 Type MiniScroll
Main
 Case message of
  SingleClic :
  Begin
   ChangeTitle 25 (GetValue 23)
  End
End

Widget 24
Property
 Size 25 25
 Position 30 277
 Type ItemDraw
 Title {Opaque move size (%):}
Main
 Case message of
  SingleClic :
  Begin
  End
End

Widget 25
Property
 Position 206 277
 Type ItemDraw
 Title {100}
Main
 Case message of
  SingleClic :
  Begin
  End
End


